visible

set [the] visible of button to trueOrFalse

set [the] visible of field to trueOrFalse

set [the] visible of window to trueOrFalse

set the visible of externalWindow to trueOrFalse

set [the] visible of menuBar to trueOrFalse

The visible property returns or sets whether a button, field, window, or the menu bar is visible on the screen.

With external windows, an external command or external function must first create a window before the visible will work on it. Setting the visible of a window to true (showing it) will not create the window. Similarly, setting the visible of a window to false (hiding it) doesn't remove it from the window list (from memory); use the close command to dispose of a window.

Examples

the visible of card button 1

the visible of bkgnd field id 34

the visible of message box

the visible of tool window

the visible of card window

the visible of message watcher

the visible of variable watcher

set the visible of bkgnd button "Next" to false

set the visible of card window to true

set the visible of field 1 to not (the visible of field 1)

Demo Script

on flashButton

hideShowObject "bkgnd btn id 57", 6

end flashButton

on hideShowObject whatObject, howManyTimes

repeat for (howManyTimes * 2) times

set the visible of whatObject to not the visible of whatObject

end repeat

end hideShowObject

Related Topics

Placeholders

button

An expression that identifies a button by name, number, or id, using one of the following forms:

[card] button id posInteger [of card]

[card] button text [of card] -- name

[card] button posInteger [of card]

ordinal [card] button [of card]

bkgnd button id posInteger [of card]

bkgnd button text [of card] -- name

bkgnd button posInteger [of card]

ordinal bkgnd button [of card]

card button id 3894

card button "Return"

card button 1

first card button

bkgnd button 2 of card 2

last bkgnd button

A button can also be referred to as a part when you’re talking about its position among all buttons and fields within the same card or background.

An expression that identifies a button by name, number, or id, using the same forms as HyperTalk except that “background” must be used in place of “bkgnd”.

trueOrFalse

Any expression that evaluates to the HyperTalk and AppleScript constants true or false.

true

false

the hilite of bg btn "Yes"

fld "Zip" contains "95014"

the short name of this stack is "Fred"

field

An expression that identifies a field by name, number, or id using one of the following forms (in AppleScript, use “background” in place of “bkgnd”):

card field id posInteger [[of] card]

card field text [of card] -- name

card field posInteger [of card]

ordinal card field [of card]

[bkgnd] field id posInteger [of card]

[bkgnd] field text [of card] -- name

[bkgnd] field posInteger [of card]

ordinal [bkgnd] field [of card]

For example:

When used inside a field script in HyperTalk: `me`

When a field receives a message: `[the] target`

A field can also be referred to as a part when you’re talking about its position among all buttons and fields within the same card or background.

window

One of HyperCard’s built-in windows, the window containing the current stack (called the card window), or any other window containing a stack, as follows:

card window

tool window

window "tools"

pattern window

window "Patterns"

scroll window

window "scroll"

[the] message [window]

[the] message [box]

[the] msg [window]

[the] msg [box]

window "message"

message watcher

window "message watcher"

variable watcher

window "variable watcher"

window "Home"

window "Readymade Buttons"

-- if longWindowTitles is true:

window "My HD:Home"

window 6

window ID 21403082

Note: If a window containing a stack is inactive, you can set only its location and visible properties.

Important: External windows can’t be substituted for the window placeholder (see the externalWindow placeHolder).

externalWindow

A window displayed by an external command or an external function; a window that’s not one of HyperCard’s built-in windows:

window "navigator"

window "Script of stack My HD:Home"

window "JT's Cool Palette"